TES4-輝輪酸紀行

PCゲーム「oblivion」のRP小説とMOD解説感想などなど。

スポンサーサイト

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。
  1. --/--/--(--) --:--:--|
  2. スポンサー広告

【CS・ツール】ノクターナルの灰色頭巾のスクリプトを解読してみる

Modder向け記事…なのかな?

グレイフォックスさんの被ってるアレについて解説してみます。
また悪い事に使えないかと思って調べてたので、完璧に覚え書きです。











ScriptName TGGrayCowlScript

;定義の設定

Float GFCrimeGold ;Gray Fox Cowlを装備した時にかけられる賞金
Float GFInfamy ;Gray Fox Cowlを装備した時の悪声
Float GFFame ;Gray Fox Cowlを装備した時の名声

Float PCCrimeGold ;Gray Fox Cowlを装備する前のプレイヤーの賞金
Float PlayerInfamy ;Gray Fox Cowlを装備する前のプレイヤーの悪名
Float PlayerFame ;Gray Fox Cowlを装備する前のプレイヤーの名声

Float TempCrime ;Gray Fox Cowlの賞金額の初期値





Begin OnEquip Player ;Gray Fox Cowlを装備した時

 ;グレイフォックス状態の賞金額の設定

 If ( GetPlayerInSEWorld == 0 ) ;プレイヤーがShivering Islesにいない時

  Set TempCrime to GetGameSetting iCrimeGoldAttackMin
  ;ガードがプレイヤーを追い始める最低賞金額?をTempCrimeと定義

  If ( GFCrimeGold < TempCrime ) ;更にGFCrimeGoldがTempGoldより小さい場合
   Set GFCrimeGold to TempCrime ;GFCrimeGoldの値をTempCrimeの値として定義する
  EndIf

  Set PCCrimeGold to Player.GetCrimeGold ;プレイヤーの現在の賞金額をPCCrimeGoldに保存
  Player.SetCrimeGold GFCrimeGold
  ;プレイヤーの賞金額をGFCrimeGoldの値(グレイフォックスの賞金額)に設定
 EndIf


 ;名声値の設定

 Set PlayerFame to GetPCFame ;プレイヤーの現在の名声をPlayerFameに保存
 SetPCFame GFFame ;プレイヤーの名声をGFFameにコピー

 ;※グレイフォックス時に名声が上がってもプレイヤーには加算されない
 ;グレイフォックス時の名声値は常にプレイヤーと同じ


 ;悪名の設定

 If ( GFInfamy < 100 ) ;もしGFInfamy(グレイフォックスの悪名が)100未満の場合
  Set GFInfamy to 100 ;GFInFamyの値を100に定義する
  ;※この処理によりグレイフォックス時に悪名が増減しても装備を脱着すれば常に100になる
 EndIf

 Set PlayerInfamy to GetPCInfamy ;プレイヤーの現在の悪名をPlayerInfamyに記録
 SetPCInfamy GFInfamy ;プレイヤーの悪名をGFInfamyの値(グレイフォックスの悪名=100)にセット

End





Begin OnUnequip Player ;Gray Fox Cowlを脱いだ時

 If ( GetPlayerInSEWorld == 0 ) ;プレイヤーがShivering Islesにいない時
  Set GFCrimeGold to Player.GetCrimeGold ;グレイフォックスの現在の賞金額をGFCrimeGoldに登録する
  Player.SetCrimeGold PCCrimeGold ;プレイヤーの賞金額を装備前に戻す
 EndIf

 Set GFFame to GetPCFame ;グレイフォックスの現在の名声をGFFameに登録する
 SetPCFame PlayerFame ;プレイヤーの名声を装備前に戻す

 Set GFInfamy to GetPCInfamy ;グレイフォックスの現在の悪名をGFInfamyに登録する
 SetPCInfamy PlayerInfamy ;プレイヤーの悪名を装備前に戻す

End





Begin GameMode

 ;もしプレイヤーがGray Fox Cowlを装備しないでShivering Islesに入り、
 ;Shivering Isles内で装備した状態でシロディールに帰る時、シロディールの賞金計算に戻す。

 If ( GetPlayerInSEWorld == 0 ) ;プレイヤーがShivering Islesにいない時
  If ( SECrime.LeftSECowlOn == 1 ) ;Shivering IslesでGray Fox Cowlを装備した時
   If ( SECrime.EnteredSECowlOn == 0 ) ;Gray Fox Cowlを装備しないでSIに入った時

    Set TempCrime to GetGameSetting iCrimeGoldAttackMin
    ;現在のiCrimeGoldAttackMinの値をTempCrimeに再定義

     If ( GFCrimeGold < TempCrime ) ;GFCrimeGoldがTempCrimeより小さい場合
      Set GFCrimeGold to TempCrime ;GFCrimeGoldをTempCrimeの値にセットする
     EndIf

    Set PCCrimeGold to Player.GetCrimeGold ;プレイヤーの現在の賞金額をPCCrimeGoldに再保存
    Player.SetCrimeGold GFCrimeGold ;現在の賞金額をグレイフォックスの賞金額の値に再設定

    Set SECrime.LeftSECowlOn to 0 ;Gray Fox CowlのSIフラグをオフにする
   EndIf
  EndIf
 EndIf


 ;もしプレイヤーがGray Fox Cowlを装備してShivering Islesに入り、
 ;Shivering Isles内で装備しないでシロディールに帰る時、シロディールの賞金計算に戻す。

 If ( SECrime.LeftSECowlOn == 0 ) ;Shivering IslesでGray Fox Cowlを装備しなかった時
  If ( SECrime.EnteredSECowlOn == 1 ) ;Gray Fox Cowlを装備してSIに入った時

   Set GFCrimeGold to Player.GetCrimeGold ;GFCrimeGoldをプレイヤーの現在の賞金額の値にセットする
   Player.SetCrimeGold PCCrimeGold ;プレイヤーの賞金額を装備前に戻す

   Set SECrime.EnteredSECowlOn to 0 ;Gray Fox CowlのSIフラグをオフにする
  
  EndIf
 EndIf

End









SI関連の処理についてはフラグを最後まで追いきれなかったので若干自信が無いですが、
多分SIとシロディールでiCrimeGoldAttackMinとやらのグローバル関数の値が違うので
その辺の処理を最後に行っているのかなと。
あとはSECrime.LeftSECowlOnがどこのスクリプトで1に設定されてるのか分からず…


名声・悪名・賞金額の設定については書いた通りです。
応用すれば装備中は善人に見える仮面なんてのも作れそうですね。



・・・などと言ってみるけど
具体的に面白い使い方が思いつかないなあ。




スポンサーサイト

テーマ:Oblivion - ジャンル:ゲーム

  1. 2012/04/21(土) 00:04:03|
  2. CS・ツール
  3. | トラックバック:0
  4. | コメント:0
<<【自作MOD】Conduit Magic Ver.0.8 しとしん版準拠日本語化パッチ | ホーム | 【雑記】ロードリスト覚え書き>>

コメント

コメントの投稿


管理者にだけ表示を許可する

トラックバック

トラックバック URL
http://kirinsasidchemistry.blog47.fc2.com/tb.php/270-49992874
この記事にトラックバックする(FC2ブログユーザー)

プロフィール

天気輪

Author:天気輪
天気輪(てん・きりん)

PS3版をプレイ後、
PC新調を機に2009年6月から
TES4 oblivionを開始。

Twitter@Tengkiring


このサイトはリンクフリーです。

カウンター

Visit:

Now Online:

検索フォーム

最新記事

カテゴリ

はじめに (1)
登場人物紹介 (4)
もくじ(RP小説) (3)
RP小説-メインクエ篇 (121)
RP小説-戦士ギルド篇 (15)
RP小説外伝-青鬼篇 (20)
RP小説外伝-しろメル篇 (11)
RP小説外伝-短篇 (2)
もくじ(自作MOD) (1)
自作MOD (20)
もくじ(その他) (1)
CS・ツール (20)
MOD紹介 (29)
他作MOD配布 (1)
Legend of Diva攻略 (5)
雑記 (53)
Fallout3/NewVegas (5)
他のゲーム (5)
戯言 (8)
事故創作 (1)
未分類 (0)

ブログ記事ランキング

最新コメント

リンク

このブログをリンクに追加する

月別アーカイブ

World-Word-翻訳

英語English
韓国語 한국어
中国語 中文
フランス語 Franc,ais
ドイツ語 Deutsch
イタリア語L'italiano
スペイン語 Espan~ol
ポルトガル語 Portugue^s
Present's by サンエタ
英語English
韓国語 한국어
中国語 中文
フランス語 Franc,ais
ドイツ語 Deutsch
イタリア語L'italiano
スペイン語 Espan~ol
ポルトガル語 Portugue^s
Present's by サンエタ

Twitter

アンケート

無料アクセス解析

RSSリンクの表示

ブロとも申請フォーム

この人とブロともになる

上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。